示例：读取标签的值和数据

Dim WithEvents oGroup As TagGroup
Sub SetUpTagGroup()
  On Error Resume Next
  Err.Clear
  If oGroup Is Nothing Then
    Set oGroup = Application.CreateTagGroup(Me.AreaName, 500)
    If Err.Number Then
      LogDiagnosticsMessage "Error creating TagGroup. Error: " _
        & Err.Description, ftDiagSeverityError
      Exit Sub
    End If
    oGroup.Add "System\Second"
    oGroup.Add "System\Minute"
    oGroup.Active = True
  End If
End Sub
Sub ShowTagDataInfo()
  On Error Resume Next
  Dim oTag As Tag
  Dim Value as Variant
  Dim TimeStamp as Date
  Dim Quality as tagQualityConstants
  Dim SubStatus as tagSubStatusConstants
  Dim Limit as tagLimitConstants
  If Not oGroup Is Nothing Then
    Set oTag = oGroup.Item("System\Second")
    Err.Clear
    oTag.GetTagData Value, TimeStamp, Quality, SubStatus, Limit, TRUE
    Select Case Err.Number
      Case 0:
        ' Read was successful
        MsgBox "Tag Name: " & oTag.Name & vbCrLf & _
        "Value = " & Value & vbCrLf & _
        "Quality = " & Switch(Quality = tagQualityGood, "Good", _
        Quality = tagQualityBad, "Bad", _
        Quality = tagQualityUncertain, "Uncertain") _
        & vbCrLf & _
        "Timestamp = " & TimeStamp
      Case tagErrorReadValue:
        MsgBox "Error to reading tag value of " & oTag.Name & ". Error: " & _
        oTag.LastErrorNumber
      Case tagErrorOperationFailed:
        MsgBox "Failed to read from tag " & oTag.Name & ". Error: " & Err.Description
    End Select
  End If
End Sub